浅谈flex中的绑定问题

先看一个比较正常的代码：

 

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
	<mx:Script>
		<![CDATA[
			import cn.whitecrystal.ObjectA;
			[Bindable]
			private var objectA:ObjectA = new ObjectA();
		]]>
	</mx:Script>
	<mx:Label x="10" y="10" text="{objectA.objectB.aLabel}" width="106"/>
	<mx:Button x="136" y="8" label="Button" click="objectA.objectB.aLabel='HELLO'"/>
</mx:Application>

 ObjectA的代码：

package cn.whitecrystal
{
	[Bindable]
	public class ObjectA
	{	
		public var objectB:ObjectB = new ObjectB();
	}
}

 ObjectB的代码：

package cn.whitecrystal
{
	[Bindable]
	public class ObjectB
	{
		public var aLabel:String = "this is a label";
	}
}

    很显然，当我点击按按钮的时候，Label的文字马上更新的，这就是flex的绑定了。

    但是，我们平常碰到的代码可以不会这么正常。我们假设Object B是一个小白写的，写成这样：

package cn.whitecrystal
{
	public class ObjectB
	{
		public var aLabel:String = "this is a label";
	}
}

   很不幸，这样这样即使你更新实例中aLabel的值，banding也不会生效的。其实这在我们实际开发中更为常见，因为第三方开发包的源码不开源的时候，你又有这种需求就得瞪眼了。

   当然书上不会教你这些东西，一切开发中的tip要由小白林毓颖来告诉更多的菜鸟们，大鸟们从来不说嘀嘀嘀。

   方法当然有很多种，这里介绍其中一个吧：

   保持类的封装当然是我们的最终目的：

   所以选择修改ObjectA如下：

package cn.whitecrystal
{
	import mx.utils.ObjectProxy;	
	[Bindable]
	public class ObjectA
	{	
		
		private var temp:ObjectB = new ObjectB();
		public var objectB:ObjectProxy = new ObjectProxy(temp);
	}
}

 

ObjectProxy当然是一个重要的架桥类，具体大家见文档吧。